如何从客户端 VBScript 自动化 Excel - 梦缘居士的日志

本页

概要

更多信息

示例代码

参考

概要

本文介绍在用户单击网页上的按钮时启动并自动化 Microsoft Excel 的 VBScript 客户端代码。

回到顶端

更多信息

示例代码

在任意文本编辑器中创建下面的 HTML 文件并将该文件保存为 c:\excel.htm。

<HTML>
<BODY>

<INPUT id=button1 name=button1 type=button value=Button>

<SCRIPT LANGUAGE="VBScript">

       sub button1_onclick()

          ' Launch Excel
          dim app
          set app = createobject("Excel.Application")
    
          ' Make it visible
          app.Visible = true
    
          ' Add a new workbook
          dim wb
          set wb = app.workbooks.add
    
          ' Fill array of values first...
          dim arr(19,9) ' Note: VBScript is zero-based
          for i = 1 to 20
             for j = 1 to 10
                arr(i-1,j-1) = i*j
             next
          next
    
          ' Declare a range object to hold our data
          dim rng
          set rng = wb.Activesheet.Range("A1").Resize(20,10)
    
          ' Now assign them all in one shot...
          rng.value = arr
    
          ' Add a new chart based on the data
          wb.Charts.Add
          wb.ActiveChart.ChartType = 70 'xl3dPieExploded
          wb.ActiveChart.SetSourceData rng, 2 ' xlColumns
          wb.ActiveChart.Location 2, "Sheet1" 'xlLocationAsObject
    
          ' Rotate it around...
          for i = 1 to 360 step 30
             wb.activechart.rotation = i
          next

          ' Give the user control of Excel
          app.UserControl = true

       end sub
</SCRIPT>

</BODY>
</HTML>

2. 启动 Internet Explorer，在地址栏中键入 c:\excel.htm，然后按 Enter。

结果：在 Excel 中出现一个新的工作簿。新工作簿中的 Sheet1 包含数据并创建了一个新图表。新图表是旋转形状。

注意：如果在单击网页上的按钮时收到错误“ActiveX component can't create object 'createobject'”，请按照本文“参考”一节列出的文章中的说明检查您的安全设置。

回到顶端

参考

有关其他信息，请单击下面的文章编号，以查看 Microsoft 知识库中相应的文章：

195826 (http://support.microsoft.com/kb/195826/) PRB：客户端脚本中的 CreateObject 失败